Le cycle GAP du RPG, la boucle qu'on ne voit pas

Niveau 1 Découvrir : un programme sans boucle

Lire et imprimer un fichier sans écrire de boucle

Le fichier de démonstration contient six ventes fictives, triées par région. Sa description DDS :

     A          R CYCVTR                    TEXT('Ventes par client')
     A            REGION        10A         TEXT('Region')
     A            CLIENT        20A         TEXT('Client')
     A            MONTNT         7P 2       TEXT('Montant')

Voici un programme RPG/400 complet qui imprime ces six ventes. Lisez-le : il n'y a aucune spécification de calcul (ligne C), donc ni boucle, ni lecture, ni test de fin de fichier.

*...+....1....+....2....+....3....+....4....+....5....+....6....+....7....+....8
     H
     F* Niveau 1 : le cycle lit, imprime et s'arrete tout seul
     FCYCVTE  IP  E                    DISK
     FQSYSPRT O   F     132     OF     PRINTER
     ICYCVTR      01
     OQSYSPRT H  201   1P
     O       OR        OF
     O                                   24 'VENTES PAR CLIENT'
     O        D  1     01
     O                         REGION    12
     O                         CLIENT    34
     O                         MONTNTJ   46

IP (ligne F de CYCVTE)

I pour entrée, P pour primaire : c'est ce fichier que le cycle lit tout seul. C'est cette lettre P qui met le cycle en route.

01 (ligne I)

Indicateur allumé par le cycle chaque fois qu'il lit un enregistrement du format CYCVTR.

H … 1P

Ligne d'en-tête imprimée au premier cycle (1P, first page) et à chaque nouvelle page (OF).

D … 01

Ligne de détail, imprimée à chaque cycle où un enregistrement a été lu.

Résultat réel, compilé par CRTRPGPGM et exécuté sur IBM i 7.5 (spoule QSYSPRT) :

       VENTES PAR CLIENT
  NORD        DUPONT                   120.00
  NORD        MARTIN                    80.50
  OUEST       DURAND                    75.00
  SUD         BERNARD                  200.00
  SUD         PETIT                     50.00
  SUD         ROBERT                    30.00

Le programme s'est arrêté seul : à la lecture qui suit ROBERT, le cycle a trouvé la fin du fichier, allumé LR (last record) et terminé le programme.

Dans le débogueur, la touche F5 (pas à pas) montre ce que le cycle exécute. Pour CYCLE1, les arrêts se succèdent ainsi : 600 800 900 500 700 500 600 900 1000 1100 1200 … L'instruction 500 (la ligne I) revient deux fois par cycle : une fois pour la lecture, une fois pour le transfert des zones. Et chaque ligne de détail s'imprime au début du cycle suivant (600 à 1200), juste avant la lecture d'après.

Niveau 2 Maîtriser : ruptures, totaux et ordre exact

Sous-totaux par région : la rupture de contrôle L1

Ajoutons des sous-totaux par région, un compteur de clients et un total général. Toujours sans boucle :

*...+....1....+....2....+....3....+....4....+....5....+....6....+....7....+....8
     H
     F* Niveau 2 : rupture L1 sur la region, totaux et LR
     FCYCVTE  IP  E                    DISK
     FQSYSPRT O   F     132     OF     PRINTER
     ICYCVTR      01
     I              REGION                          REGIONL1
     C* Calculs de detail : a chaque enregistrement lu
     C   01      TOTREG    ADD  MONTNT    TOTREG  92
     C   01      NBCLI     ADD  1         NBCLI   30
     C* Calculs de total : au changement de region
     CL1         TOTGEN    ADD  TOTREG    TOTGEN 112
     OQSYSPRT H  201   1P
     O       OR        OF
     O                                   24 'VENTES PAR REGION'
     O        D  1     01
     O                         REGION    12
     O                         CLIENT    34
     O                         MONTNTJ   46
     O        T  2     L1
     O                                   19 'TOTAL'
     O                         REGION    30
     O                         TOTREGJB  46
     O                         NBCLI ZB  52
     O                                   62 'CLIENT(S)'
     O        T  1     LR
     O                                   27 'TOTAL GENERAL'
     O                         TOTGENJ   46

Numéros d'instruction : STRISDB numérote les lignes du membre source de 100 en 100. La 5^e ligne (la ligne I) est l'instruction 500, la 11^e (le calcul de total) l'instruction 1100, et ainsi de suite.

REGION … L1 (ligne I)

REGION devient zone de contrôle de niveau 1 : quand sa valeur change d'un enregistrement à l'autre, le cycle allume L1.

Lignes C sans niveau (800, 900)

Calculs de détail, faits à chaque enregistrement (indicateur 01).

CL1 (1100)

Calcul de total, fait seulement quand L1 est allumé : on ajoute le total de la région au total général.

Lignes T … L1 et T … LR

Sorties de total. Le B (blank after) remet TOTREG et NBCLI à zéro après l'impression.

Résultat réel, compilé par CRTRPGPGM et exécuté sur IBM i 7.5 (spoule QSYSPRT) :

       VENTES PAR REGION
  NORD        DUPONT                   120.00
  NORD        MARTIN                    80.50
              TOTAL NORD               200.50      2 CLIENT(S)
  OUEST       DURAND                    75.00
              TOTAL OUEST               75.00      1 CLIENT(S)
  SUD         BERNARD                  200.00
  SUD         PETIT                     50.00
  SUD         ROBERT                    30.00
              TOTAL SUD                280.00      3 CLIENT(S)
              TOTAL GENERAL            555.50

Le cycle pas à pas : la mémoire à chaque étape

Avancez étape par étape dans CYCLE2 et regardez ce que le cycle fait de la mémoire : l'enregistrement qui attend dans le tampon d'entrée, les variables du programme, les indicateurs 1P, 01, L1, OF et LR, et l'état qui s'imprime. Les lignes du source en vert sont celles que le cycle exécute, celles barrées sont examinées puis sautées. Les 47 étapes suivent l'ordre relevé dans STRISDB, et l'état obtenu est celui du spoule réel.

 100 H 200 F* Niveau 2 : rupture L1 sur la region, totaux et LR 300 FCYCVTE  IP  E                    DISK 400 FQSYSPRT O   F     132     OF     PRINTER 500 ICYCVTR      01 600 I              REGION                          REGIONL1 700 C* Calculs de detail : a chaque enregistrement lu 800 C   01      TOTREG    ADD  MONTNT    TOTREG  92 900 C   01      NBCLI     ADD  1         NBCLI   301000 C* Calculs de total : au changement de region1100 CL1         TOTGEN    ADD  TOTREG    TOTGEN 1121200 OQSYSPRT H  201   1P1300 O       OR        OF1400 O                                   24 'VENTES PAR REGION'1500 O        D  1     011600 O                         REGION    121700 O                         CLIENT    341800 O                         MONTNTJ   461900 O        T  2     L12000 O                                   19 'TOTAL'2100 O                         REGION    302200 O                         TOTREGJB  462300 O                         NBCLI ZB  522400 O                                   62 'CLIENT(S)'2500 O        T  1     LR2600 O                                   27 'TOTAL GENERAL'2700 O                         TOTGENJ   46

       VENTES PAR REGION

Le déroulé réel, relevé dans STRISDB

Nous avons lancé STRISDB PGM(CYCLE2) et appuyé sur F5 jusqu'à la fin du programme : 98 arrêts. Le débogueur s'arrête sur chaque ligne que le cycle examine, y compris celles dont la condition est fausse. Voici ces arrêts, découpés en cycles :

Repères : 500 = la ligne I (lecture, puis transfert des zones), 800-900 = calculs de détail, 1100 = calcul de total, 1200-1800 = en-tête et détail, 1300 = débordement (OF), 1900-2400 = total de région, 2500-2700 = total général.

La preuve : au moment du total, les variables ont encore l'ancien groupe

Un point d'arrêt sur la ligne 1100 (BREAK 1100, puis F17 pour exécuter) arrête le programme au calcul de total. Au deuxième arrêt, le cycle vient de lire DURAND, de la région OUEST : c'est ce changement de région qui a allumé L1. Pourtant, F11 sur REGION affiche NORD, et TOTREG vaut 200,50, le total de NORD.

On avance ensuite en pas à pas : les lignes 2000 à 2400 impriment « TOTAL NORD », 1300 teste le débordement, puis 500 transfère enfin les zones de DURAND. Arrivé au calcul de détail (800), REGION vaut OUEST et TOTREG a été remis à zéro par le B de la sortie de total.

C'est la caissière qui imprime le ticket de l'ancien client avant de biper l'article du nouveau. En fin de fichier, la fenêtre « Fin du programme » apparaît après l'instruction 2700, la dernière ligne du total général :

Les pièges du niveau 2

• Pas de total au premier enregistrement. Le premier enregistrement allume bien L1 (sa région diffère de « rien »), mais le cycle saute les calculs et les sorties de total à ce moment-là. Un calcul L1 n'est donc pas un bon endroit pour initialiser quelque chose avant le premier groupe : utilisez 1P ou les calculs de détail conditionnés par L1.
• Au total, les variables appartiennent au groupe qui se termine. Un calcul de total qui utilise une zone de l'enregistrement lu (MONTNT, CLIENT) prend celle du dernier enregistrement du groupe précédent, pas celle du nouvel enregistrement.
• LR allume aussi L1 à L9. En fin de fichier, tous les niveaux sont fermés : le dernier groupe a son total (TOTAL SUD) avant le total général. Inutile de le coder à part.
• Le débogueur s'arrête sur des lignes qui ne s'exécutent pas. ISDB s'arrête sur 1100 à chaque cycle, même sans rupture : il montre la ligne que le cycle examine, la condition L1 est testée ensuite. Seuls les arrêts sur 2000 à 2400 prouvent qu'un total s'imprime.
• Une zone éditée prend plus de place qu'on ne le croit. En écrivant ce programme, le nombre de clients était d'abord placé en position 35 : il n'apparaissait jamais. TOTREG (9 chiffres) édité par le code J occupe 13 positions, de 34 à 46, et recouvrait le compteur, sans aucun message du compilateur.
• Une zone de contrôle d'un fichier décrit en externe s'écrit en deux fois. En RPG/400, la ligne I doit porter le nom externe en positions 21-30 et le nom RPG en 53-58, puis L1 en 59-60. Sans le nom en 53-58, la compilation échoue (QRG4119) ; sans le nom externe, aussi (QRG4078).

Le même programme sans cycle

Pour mesurer ce que le cycle fait à votre place, voici le même état en RPG IV full free, avec une boucle explicite. Il a été compilé par CRTBNDRPG et exécuté sur le même fichier : son état imprimé est identique, ligne pour ligne, à celui de CYCLE2.

**free
// Le même état que CYCLE2, sans le cycle : tout ce qu'il faisait est écrit à la main
ctl-opt dftactgrp(*no) actgrp(*new);

dcl-f CYCVTE usage(*input);            // plus de IP : on lit soi-même
dcl-f QSYSPRT printer(132);

dcl-ds ligne len(132);
  zone char(132) pos(1);
end-ds;

dcl-s regionPrec char(10);
dcl-s totReg packed(9:2);
dcl-s nbCli packed(3:0);
dcl-s totGen packed(11:2);
dcl-s premier ind inz(*on);

imprimer(8 : 'VENTES PAR REGION');      // ce que faisait la ligne H conditionnée par 1P
imprimer(1 : '');

read CYCVTR;                            // étape 2 du cycle : lire
dow not %eof(CYCVTE);
  if not premier and REGION <> regionPrec;
    totalRegion();                      // la rupture L1, détectée à la main
  endif;
  premier = *off;
  regionPrec = REGION;

  totReg += MONTNT;                     // calculs de détail
  nbCli += 1;

  zone = *blanks;                       // sortie de détail
  %subst(zone : 3 : 10) = REGION;
  %subst(zone : 15 : 20) = CLIENT;
  %subst(zone : 37 : 10) = %editc(MONTNT : 'J');
  write QSYSPRT ligne;

  read CYCVTR;
enddo;

if not premier;                         // à LR, le cycle fait aussi le dernier L1
  totalRegion();
endif;
zone = *blanks;
%subst(zone : 15 : 13) = 'TOTAL GENERAL';
%subst(zone : 32 : 15) = %editc(totGen : 'J');
write QSYSPRT ligne;

*inlr = *on;
return;

dcl-proc imprimer;
  dcl-pi *n;
    colonne int(10) const;
    texte varchar(132) const;
  end-pi;
  zone = *blanks;
  if %len(texte) > 0;
    %subst(zone : colonne : %len(texte)) = texte;
  endif;
  write QSYSPRT ligne;
end-proc;

dcl-proc totalRegion;
  totGen += totReg;                     // ce que faisait la ligne de calcul L1
  zone = *blanks;
  %subst(zone : 15 : 5) = 'TOTAL';
  %subst(zone : 21 : 10) = regionPrec;
  %subst(zone : 34 : 13) = %editc(totReg : 'J');
  %subst(zone : 50 : 3) = %editc(nbCli : 'Z');
  %subst(zone : 54 : 9) = 'CLIENT(S)';
  write QSYSPRT ligne;
  imprimer(1 : '');
  totReg = 0;                           // le B (blanc après) des spécifications O
  nbCli = 0;
end-proc;

Tout ce que le cycle cachait devient visible : la lecture (read), la boucle (dow not %eof), la détection de rupture (comparer REGION à la valeur précédente), le cas du premier enregistrement (premier), le dernier total à la fin du fichier, et la remise à zéro. Plus long, mais lisible par n'importe quel développeur.